2. EBNF Grammar of Lojban

This EBNF document is explicitly dedicated to the public domain by its author, The Logical Language Group, Inc. Contact that organization at: 2904 Beau Lane, Fairfax VA 22031 USA 703-385-0273 (intl: +1 703 385 0273)

Explanation of notation: All rules have the form:

name_number = bnf-expression

1. Names in lower case are grammatical constructs.
2. Names in UPPER CASE are selma'o (lexeme) names, and are terminals.
3. Concatenation is expressed by juxtaposition with no operator symbol.
4. | represents alternation (choice).
5. [] represents an optional element.
6. & represents and/or (“A & B” is the same as “A | B | A B”).
7. ... represents optional repetition of the construct to the left. Left-grouping is implied; right-grouping is shown by explicit self-referential recursion with no “...”
8. () serves to indicate the grouping of the other operators. Otherwise, “...” binds closer than &, which binds closer than |.
9. # is shorthand for “[free ...]”, a construct which appears in many places.
10. // encloses an elidable terminator, which may be omitted (without change of meaning) if no grammatical ambiguity results.

text₀ =

[NAI ...] [CMENE ... # | (indicators & free ...)] [joik-jek] text-1

text-1₂ =

[(I [jek | joik] [[stag] BO] #) ... | NIhO ... #] [paragraphs]

paragraphs₄ =

paragraph [NIhO ... # paragraphs]

paragraph₁₀ =

(statement | fragment) [I # [statement | fragment]] ...

statement₁₁ =

statement-1
| prenex statement

statement-1₁₂ =

statement-2 [I joik-jek [statement-2]] ...

statement-2₁₃ =

statement-3 [I [jek | joik] [stag] BO # [statement-2]]

statement-3₁₄ =

sentence
| [tag] TUhE # text-1 /TUhU#/

fragment₂₀ =

ek #
| gihek #
| quantifier
| NA #
| terms /VAU#/
| prenex
| relative-clauses
| links
| linkargs

prenex₃₀ =

terms ZOhU #

sentence₄₀ =

[terms [CU #]] bridi-tail

subsentence₄₁ =

sentence
| prenex subsentence

bridi-tail₅₀ =

bridi-tail-1 [gihek [stag] KE # bridi-tail /KEhE#/ tail-terms]

bridi-tail-1₅₁ =

bridi-tail-2 [gihek # bridi-tail-2 tail-terms] ...

bridi-tail-2₅₂ =

bridi-tail-3 [gihek [stag] BO # bridi-tail-2 tail-terms]

bridi-tail-3₅₃ =

selbri tail-terms
| gek-sentence

gek-sentence₅₄ =

gek subsentence gik subsentence tail-terms
| [tag] KE # gek-sentence /KEhE#/
| NA # gek-sentence

tail-terms₇₁ =

[terms] /VAU#/

terms₈₀ =

terms-1 ...

terms-1₈₁ =

terms-2 [PEhE # joik-jek terms-2] ...

terms-2₈₂ =

term [CEhE # term] ...

term₈₃ =

sumti | (tag | FA #) (sumti
| /KU#/)
| termset
| NA KU #

termset₈₅ =

NUhI # gek terms /NUhU#/ gik terms /NUhU#/
| NUhI # terms /NUhU#/

sumti₉₀ =

sumti-1 [VUhO # relative-clauses]

sumti-1₉₁ =

sumti-2 [(ek | joik) [stag] KE # sumti /KEhE#/]

sumti-2₉₂ =

sumti-3 [joik-ek sumti-3] ...

sumti-3₉₃ =

sumti-4 [(ek
| joik) [stag] BO # sumti-3]

sumti-4₉₄ =

sumti-5
| gek sumti gik sumti-4

sumti-5₉₅ =

[quantifier] sumti-6 [relative-clauses]
| quantifier selbri /KU#/ [relative-clauses]

sumti-6₉₇ =

(LAhE # | NAhE BO #) [relative-clauses] sumti /LUhU#/
| KOhA #
| lerfu-string /BOI#/
| LA # [relative-clauses] CMENE ... #
| (LA | LE) # sumti-tail /KU#/
| LI # mex /LOhO#/
| ZO any-word #
| LU text /LIhU#/
| LOhU any-word ... LEhU #
| ZOI any-word anything any-word #

sumti-tail₁₁₁ =

[sumti-6 [relative-clauses]] sumti-tail-1
| relative-clauses sumti-tail-1

sumti-tail-1₁₁₂ =

[quantifier] selbri [relative-clauses]
| quantifier sumti

relative-clauses₁₂₁ =

relative-clause [ZIhE # relative-clause] ...

relative-clause₁₂₂ =

GOI # term /GEhU#/
| NOI # subsentence /KUhO#/

selbri₁₃₀ =

[tag] selbri-1

selbri-1₁₃₁ =

selbri-2
| NA # selbri

selbri-2₁₃₂ =

selbri-3 [CO # selbri-2]

selbri-3₁₃₃ =

selbri-4 ...

selbri-4₁₃₄ =

selbri-5 [joik-jek selbri-5 | joik [stag] KE # selbri-3 /KEhE#/] ...

selbri-5₁₃₅ =

selbri-6 [(jek | joik) [stag] BO # selbri-5]

selbri-6₁₃₆ =

tanru-unit [BO # selbri-6]
| [NAhE #] guhek selbri gik selbri-6

tanru-unit₁₅₀ =

tanru-unit-1 [CEI # tanru-unit-1] ...

tanru-unit-1₁₅₁ =

tanru-unit-2 [linkargs]

tanru-unit-2₁₅₂ =

BRIVLA #
| GOhA [RAhO] #
| KE # selbri-3 /KEhE#/
| ME # sumti /MEhU#/ [MOI #] | (number
| lerfu-string) MOI #
| NUhA # mex-operator
| SE # tanru-unit-2
| JAI # [tag] tanru-unit-2
| any-word (ZEI any-word) ...
| NAhE # tanru-unit-2
| NU [NAI] # [joik-jek NU [NAI] #] ... subsentence /KEI#/

linkargs₁₆₀ =

BE # term [links] /BEhO#/

links₁₆₁ =

BEI # term [links]

quantifier₃₀₀ =

number /BOI#/
| VEI # mex /VEhO#/

mex₃₁₀ =

mex-1 [operator mex-1] ...
| FUhA # rp-expression

mex-1₃₁₁ =

mex-2 [BIhE # operator mex-1]

mex-2₃₁₂ =

operand
| [PEhO #] operator mex-2 ... /KUhE#/

rp-expression₃₃₀ =

rp-operand rp-operand operator

rp-operand₃₃₂ =

operand
| rp-expression

operator₃₇₀ =

operator-1 [joik-jek operator-1 | joik [stag] KE # operator /KEhE#/] ...

operator-1₃₇₁ =

operator-2
| guhek operator-1 gik operator-2
| operator-2 (jek | joik) [stag] BO # operator-1

operator-2₃₇₂ =

mex-operator
| KE # operator /KEhE#/

mex-operator₃₇₄ =

SE # mex-operator
| NAhE # mex-operator
| MAhO # mex /TEhU#/
| NAhU # selbri /TEhU#/
| VUhU #

operand₃₈₁ =

operand-1 [(ek | joik) [stag] KE # operand /KEhE#/]

operand-1₃₈₂ =

operand-2 [joik-ek operand-2] ...

operand-2₃₈₃ =

operand-3 [(ek | joik) [stag] BO # operand-2]

operand-3₃₈₅ =

quantifier
| lerfu-string /BOI#/
| NIhE # selbri /TEhU#/
| MOhE # sumti /TEhU#/
| JOhI # mex-2 ... /TEhU#/
| gek operand gik operand-3
| (LAhE # | NAhE BO #) operand /LUhU#/

number₈₁₂ =

PA [PA | lerfu-word] ...

lerfu-string₈₁₇ =

lerfu-word [PA | lerfu-word] ...

lerfu-word₉₈₇ =

BY
| any-word BU
| LAU lerfu-word
| TEI lerfu-string FOI

ek₈₀₂ =

[NA] [SE] A [NAI]

gihek₈₁₈ =

[NA] [SE] GIhA [NAI]

jek₈₀₅ =

[NA] [SE] JA [NAI]

joik₈₀₆ =

[SE] JOI [NAI]
| interval
| GAhO interval GAhO

interval₉₃₂ =

[SE] BIhI [NAI]

joik-ek₄₂₁ =

joik #
| ek #

joik-jek₄₂₂ =

joik #
| jek #

gek₈₀₇ =

[SE] GA [NAI] #
| joik GI #
| stag gik

guhek₈₀₈ =

[SE] GUhA [NAI] #

gik₈₁₆ =

GI [NAI] #

tag₄₉₁ =

tense-modal [joik-jek tense-modal] ...

stag₉₇₁ =

simple-tense-modal [(jek | joik) simple-tense-modal] ...

tense-modal₈₁₅ =

simple-tense-modal #
| FIhO # selbri /FEhU#/

simple-tense-modal₉₇₂ =

[NAhE] [SE] BAI [NAI] [KI]
| [NAhE] (time [space]
| space [time]) & CAhA [KI]
| KI
| CUhE

time₁₀₃₀ =

ZI & time-offset ... & ZEhA [PU [NAI]] & interval-property ...

time-offset₁₀₃₃ =

PU [NAI] [ZI]

space₁₀₄₀ =

VA & space-offset ... & space-interval & (MOhI space-offset)

space-offset₁₀₄₅ =

FAhA [NAI] [VA]

space-interval₁₀₄₆ =

((VEhA & VIhA) [FAhA [NAI]]) & space-int-props

space-int-props₁₀₄₉ =

(FEhE interval-property) ...

interval-property₁₀₅₁ =

number ROI [NAI]
| TAhE [NAI]
| ZAhO [NAI]

free₃₂ =

SEI # [terms [CU #]] selbri /SEhU/
| SOI # sumti [sumti] /SEhU/
| vocative [relative-clauses] selbri [relative-clauses] /DOhU/
| vocative [relative-clauses] CMENE ... # [relative-clauses] /DOhU/
| vocative [sumti] /DOhU/
| (number | lerfu-string) MAI
| TO text /TOI/
| XI # (number | lerfu-string) /BOI/
| XI # VEI # mex /VEhO/

vocative₄₁₅ =

(COI [NAI]) ... & DOI

indicators₄₁₁ =

[FUhE] indicator ...

indicator₄₁₃ =

(UI | CAI) [NAI]
| Y
| DAhO
| FUhO

The following rules are non-formal:

word₁₁₀₀ =

[BAhE] any-word [indicators]

any-word =

“any single word (no compound cmavo)”

anything =

“any text at all, whether Lojban or not”

null₁₁₀₁ =

any-word SI
| utterance SA
| text SU